0

我的帖子

个人中心

设置

  发新话题

SQL SERVER SP解密过程推导


SQL SERVER里,已知微软在加密和解密存储过程时用的是RC4算法。下面是解密存储过程的解题思路,读者可以据此自己写个解密小程序。
想解密SP,其实就是解答下列一道证明题。
已知条件:
1.
已知需要解密的存储过程SP_A的密文为Ma
2.
用一个已知明文的SP_B替换SP_A,这样得到SP_B的明文和密文分别为TbMb
求证:Ta=Ma⊕Tb⊕MbTa即为需要解密的存储过程的明文。

证明过程:
1.
DAC登录SQLSERVER,获取MaMb: SELECT imageval FROM sys.sysobjvalues where …
2.
由于RC4算法的加密和解密使用的是相同的秘钥,假设秘钥为K,那么:
a.
Mb=Tb⊕K
b.
根据异或运算公式,可以得到下列该存储过程加解秘时使用的秘钥为:
K=K⊕0=K⊕TbTb=(KTb)Tb=(Tb⊕K)Tb=MbTb
3.
因为Ma=Ta⊕K,则再次利用异或运算公式,得到下列推导结果:
Ta=Ta⊕0=Ta⊕(K⊕K)=(Ta⊕K)⊕K=Ma⊕K=Ma⊕MbTb
4.
Ta=Ma⊕Tb⊕Mb,Ta就是需要解密的存储过程的明文。

/****** Object:  StoredProcedure [dbo].[dbtwin_sp_decrypt]    Script Date: 01/01/2020 21:09:31 ******/
IF  EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[dbtwin_sp_decrypt]') AND type in (N'P', N'PC'))
DROP PROCEDURE [dbo].[dbtwin_sp_decrypt]
GO


/****** Object:  StoredProcedure [dbo].[dbtwin_sp_decrypt]    Script Date: 01/01/2020 21:09:31 ******/
SET ANSI_NULLS ON
GO


SET QUOTED_IDENTIFIER ON
GO




CREATE PROCEDURE [dbo].[dbtwin_sp_decrypt](@procname sysname = NULL)
AS
DECLARE @encrypted        NVARCHAR(MAX)
DECLARE @encryptedLength  INT


DECLARE @tempStr          NVARCHAR(MAX)
DECLARE @tempHead         NVARCHAR(MAX)
DECLARE @tempBody         NVARCHAR(MAX)


DECLARE @dummySp          NVARCHAR(MAX)
DECLARE @dummyEncrypted   NVARCHAR(MAX)


DECLARE @decryptedMessage NVARCHAR(MAX)
DECLARE @cnt              INT
DECLARE @decryptedChar    NCHAR(1)


SET NOCOUNT ON


SET @encrypted = (SELECT imageval FROM sys.sysobjvalues WHERE object_name(objid)=@procname)
SET @encryptedLength=DATALENGTH(@encrypted) / 2


SET @tempStr  = N'PROCEDURE ' + @procname + N' WITH ENCRYPTION AS'


BEGIN TRAN
SET @tempHead = N'ALTER ' + @tempStr
SET @tempBody = REPLICATE(N' ',(@encryptedLength - LEN(@tempHead)))
EXEC(@tempHead + @tempBody)
SET @dummyEncrypted = (SELECT imageval FROM sys.sysobjvalues WHERE object_name(objid)=@procname)
ROLLBACK TRAN


SET @dummySp =N'CREATE ' + @tempStr + @tempBody


SET @decryptedMessage =''
SET @cnt = 1


WHILE @cnt <> @encryptedLength
BEGIN
SET @decryptedChar =NCHAR(UNICODE(SUBSTRING(@encrypted,      @cnt, 1)) ^
                           UNICODE(SUBSTRING(@dummySp,        @cnt, 1)) ^
                           UNICODE(SUBSTRING(@dummyEncrypted, @cnt, 1)))
SET @decryptedChar=ISNULL(@decryptedChar,N' ')
SET @decryptedMessage = @decryptedMessage + @decryptedChar
SET @cnt = @cnt + 1
END
SELECT @decryptedMessage


GO





支持所有版本么?我记得2005后好像就不行了



引用:
原帖由 oswica 于 2020-1-16 19:22 发表
支持所有版本么?我记得2005后好像就不行了
记得2005后续通过profiler去抓好像是,也可以破解的



我的51CTO博客

SQL Server MCITP, MVP, MCT, DBA
引用:
原帖由 seusoftware 于 2020-2-3 14:15 发表

记得2005后续通过profiler去抓好像是,也可以破解的
很久之前试过,解密不了高版本的,后面就没试过了;

sql profiler这个只能抓到调用存储过程的sql语句 抓不到执行的代码的



‹‹ 上一贴:怎么插入带数据转换的的数据   |   下一贴:sql server 服务意外终止 ››
  发新话题
快速回复主题
关于我们 | 诚聘英才 | 联系我们 | 网站大事 | 友情链接 |意见反馈 | 网站地图
Copyright©2005-2020 51CTO.COM
本论坛言论纯属发布者个人意见,不代表51CTO网站立场!如有疑义,请与管理员联系:bbs@51cto.com